program KSP845;         { Konecne automaty v case O( An ) }

const MaxDelka = 50;    { Maximalni delka slova }

var delta : array [0..MaxDelka,char] of integer; { Prechodova funkce }
    ekviv : array [1..MaxDelka] of integer; { Pro kazdy stav je zde cislo }
                                            { nejdelsiho kratsiho "ekvi-  }
                                            { valentniho" stavu           }
    stav : integer;        { Pomocna promenna }
    c,cp : char;           {    - " -         }
    s : string;            { Vstupni slovo, pro ktere vytvarime KA }

begin
   repeat            { Nacteme vstup }
   write('Zadej vstupni slovo : ');readln(s);
   until (s<>'') and (length(s)<MaxDelka);

                     { Spocteme delta pro nulty stav }
   for c:=chr(0) to chr(255) do delta[0,c]:=0;
   delta[0,s[1]] := 1;
   ekviv[1]:=0;      { Prvni stav je ekv. nultemu }
                     { Spocteme prechodovou funkci v ostatnich stavech }
   for stav:=1 to length(s)-1 do
    begin
                     { Prechodova funkce je az na jedno stejna jako ekviv }
       for c:=chr(0) to chr(255) do delta[stav,c]:=delta[ekviv[stav],c];

       ekviv[stav+1]:= delta[stav,s[stav+1]]; { Nastavime ekviv dalsiho stavu }

       delta[stav,s[stav+1]]:=stav+1;  { Opravime tuto odlisnost }
    end;
                     { Vystup }
   writeln('Konecny automat pro toto slovo je tento:');
   writeln('KA = ( { mnozina zobr. znaku }, Q, delta, D0, { D',length(s),' } )');
   writeln(' Q = { D0 .. D',length(s),' }');
                     { Vypis funkce delta pro tisknutelne znaky }
   for stav:=0 to length(s)-1 do
    begin
       cp:=' ';
       for c:=' ' to chr(254) do
        if delta[stav,cp]<>delta[stav,c] then
         begin
            writeln('delta( D',stav,', ''',cp,''' .. ''',
                  chr(ord(c)-1),''' ) = D',delta[stav,cp]);
            cp:=c;
         end;
       write('delta( D',stav,', ''',cp,''' .. ''',chr(254),''' ) = D',delta[stav,cp]);
       writeln;
    end;
   writeln('delta( D',length(s),', '' '' .. ''',chr(254),''' ) = D',length(s));
end.