program b_pani;                      {casova slozitost O(N*N), pametova O(N)}

var Tahu,M,Smer:integer;

Function TahuVZ:integer;             {resi ulohu, pohybuje-li se BP po radku}
Var BpX,KocX,Left,Right:integer;    {pozice kocoura, BP, a omezujicich dveri}
    i,j:integer;
    s:string;
begin
  TahuVZ:=-1;BpX:=0;KocX:=0;Right:=M+1;
  for i:=1 to M do begin               			  {pro vsechny radky}
      Readln(input,s);Left:=0; {omezujici dvere nastav na obvodove zdi hradu}
      for j:=1 to M do		   {najdi kocku, BP a omezujici zdi na radku}
          case s[j] of
            '1':if (BpX>0)and(KocX>0) then begin Right:=j;break; end
                   else if (BpX>0)or(KocX>0) then exit else Left:=j;
            'A':BpX:=j;
            'B':KocX:=j;
          end;
      if KocX<>BpX then break;                      {kocka nebo BP nalezena}
  end;
  if (KocX=0)or(BpX=0) then exit;       {kocka a BP nejsou na stejnem radku}
  if Smer=2 then
      if KocX>BpX then TahuVZ:=KocX-BpX else TahuVZ:=2*Right-KocX-BpX-1;
  if Smer=3 then
      if BpX>KocX then TahuVZ:=BpX-KocX else TahuVZ:=KocX+BpX-1-2*Left;
end;

Function TahuSJ:integer;           {resi ulohu pohybuje-li se BP ve sloupci}
Var BpX,BpY,KocX,KocY,Bottom:integer; {pozice BP, kocky a omezujicich dveri}
    Top:array[1..100] of word;    {pozice moznych hornich omezujicich dveri}
    i,j:integer;
    s:string;
begin
  TahuSJ:=-1;BpX:=0;Bpy:=0;BpX:=0;KocX:=0;KocY:=0;Bottom:=M+1;
  for i:=1 to M do Top[i]:=0;
  for i:=1 to M do begin                              {ber hrad po radkach}
      Readln(input,s);
      for j:=1 to M do	       {urceni pozic kocky, BP a omezujicich dveri}
          case s[j] of
           '1':if (BpX>0)and(KocX>0) then begin Bottom:=i;break; end
                  else if (BpX>0)or(KocX>0) then exit else Top[j]:=i;
           'A':begin BpX:=j;BpY:=i;if (KocX>0)and(KocX<>BpX) then exit;end;
           'B':begin KocX:=j;KocY:=i;if (BpX>0)and(KocX<>BpX) then exit;end;
          end;
      if Bottom<>M+1 then break;   {nasli jsem uz i spodni omezujici dvere}
  end;
  if (KocX=0)or(BpX=0) then exit;    {kocka a BP nejsou ve stejnem sloupci}
  if Smer=0 then
      if BpY>KocY then TahuSJ:=BpY-KocY else TahuSJ:=BpY+KocY-2*Top[BpX]-1;
  if Smer=1 then
      if KocY>BpY then TahuSJ:=KocY-BpY else TahuSJ:=2*Bottom-BpY-KocY-1;
end;

begin
  readln(input,M,Smer);
  if Smer>1 then Tahu:=TahuVZ else Tahu:=TahuSJ;
  if Tahu=-1 then writeln('Bila pani nenajde kocoura...') else
     writeln('Najde ho v ',Tahu,' tahu.');
end.