program dul;
const MAX=100;
var N: word; { počet měst }
    nosnosti: array[1..MAX,1..MAX] of integer;     { nosnosti silnic, -1 = silnice neexistuje }
    ohodnoceni: array[1..MAX] of integer;          { nosnosti zatím nalezených cest, -1 = nekonečno }
    odkud: array[1..MAX] of integer;               { předchoži město na nejlepší cestě }
    trvaly: array[1..MAX] of boolean;              { trvale ohodnocen? }
    i,j,w:word;
    max_nosnost:integer;
procedure vypis(konec: word);
begin
  if odkud[konec]<>-1 then 
    vypis(odkud[konec]) 
  else
    write('Nalezená cesta:');
  write(' ',konec);
end;
begin
  { Nejdříve načteme popis silniční situace Kaputánii }
  readln(N);
  max_nosnost:=0;
  for i:=1 to N do
    for j:=i+1 to N do
      begin
        readln(nosnosti[i][j]);
        nosnosti[j][i]:=nosnosti[i][j];
        if max_nosnost<nosnosti[i][j] then max_nosnost:=nosnosti[i][j];
      end;
  for i:=1 to N do 
    begin
      trvaly[i]:=false;
      ohodnoceni[i]:=-1;
    end;  
  odkud[1]:=-1;
  ohodnoceni[1]:=max_nosnost;
  repeat
    w:=0;
    for i:=1 to N do
      if not(trvaly[i]) then
        if w=0 then
	  w:=i
	else
	  if ohodnoceni[i]>ohodnoceni[w] then
	    w:=i;
    if w<>0 then
      begin
        trvaly[w]:=true;
        for i:=1 to N do
	  if (nosnosti[w][i]<>-1) and not(trvaly[i]) and
	       { podmínku "not(trvaly[i])" lze vypustit }
             (ohodnoceni[i]<ohodnoceni[w]) and
               { podmínka ohodnoceni[i]<ohodnoceni[w] je vždy splněna !}
             (ohodnoceni[i]<nosnosti[w][i]) then
            begin
              if (nosnosti[w][i]<ohodnoceni[w]) then
                ohodnoceni[i]:=nosnosti[w][i]
              else
                ohodnoceni[i]:=ohodnoceni[w];
              odkud[i]:=w;
            end
      end
  until trvaly[N] or (w=0);
  if trvaly[N] then vypis(N) else write('Cesta z dolu do továrny neexistuje.');
  writeln;
end.